lk-changelog.pl (new version 0.21) vs. Linux 2.4.19-pre9 ChangeLog

[Matthias Andree]

On Tue, 28 May 2002, Marcelo Tosatti wrote:

> So here goes the last -pre. 
> 
> 
> Summary of changes from v2.4.19-pre8 to v2.4.19-pre9
> ============================================
> 
> <[e-mail]> (02/05/02 1.383.20.1)
> 	[PATCH] PATCH 2.4.19-pre7 usb-ohci and wmb()
> 

Marcelo, may I kindlny ask you for two things (Linus, #2 is for you also ;-):

1. put the _full_ _unformatted_ ChangeLog up on a website for download
   (just like it is for the 2.5 kernel) -- do not strip it down to one
   line per change

2. Use my lk-changelog.pl script with --mode=terse to reformat a summary
   for posting on the Linux-Kernel mailing list?

The script - a new version v0.21 - is below and can also be downloaded from
http://mandree.home.pages.de/linux/kernel/ in case it's been corrupted
in transit.

While it's not yet finished, I believe it to be in good enough shape to
use this.

Notable changes from the previously announced version 0.17 are:
* --mode=oneline implemented
* warns about unknown mail addresses (use --nowarn to turn this off)
* new --multi option to treat multiple logs per file
* correctly formats again with --width when many spaces or tabs are
  present

= <- if you see an equal sign followed by "3D" here, use a MIME-aware
     mailer or metamail to convert this back to a usable form
  \_ if you just see an equals sign without "3D", everything's fine

#! /usr/bin/perl -wT

# This Perl script is meant to simplify/beautify BK ChangeLogs for the linux
# kernel.
#
# (C) Copyright 2002 by Matthias Andree <[e-mail]>
#			Marcus Alanen <[e-mail]>
#			Tomas Szepe <[e-mail]>
#
# $Id: lk-changelog.pl,v 0.21 2002/05/29 11:45:48 emma Exp $
# ----------------------------------------------------------------------
# Distribution of this script is permitted under the terms of the
# GNU General Public License (GNU GPL) v2.
# ----------------------------------------------------------------------

# This program expects its input in the following format:
# (E-Mail Addresses MUST NOT bear leading whitespace!)
#
# <[e-mail]>
#	changelog text
#	more changelog text
# <[e-mail]>
#	yet another changelog
# <[e-mail]>
#	changelog #3
#	more lines
#
# and discards all changelog lines but the first after an email address,
# and groups and sorts the entries by email address:
#
# [e-mail]:
#	changelog #3
# [e-mail]
#	changelog text
#	yet another changelog

require 5.005;
use strict;

use Carp;
use Getopt::Long;
use IO::File;
eval 'use Pod::Usage;';
if ($@) {
  eval 'sub pod2usage {
    print STDERR "Usage information would be presented here if you had Pod::Usage installed.\n"
      . "Try: perl -MCPAN -e \'install Pod::Usage\'\nAbort.\n";
    exit 2;
  }';
}
use Text::ParseWords;
use Text::Tabs;
use Text::Wrap;

# --------------------------------------------------------------------
# customize the following line to change the indentation of the change
# lines, $indent1 is used for the first line of an entry, $indent for
# all subsequent lines. $indent is auto-generated from $indent1.
my $indent1 = "  o ";
my $indent  = " " x length($indent1);
# change this to enable some debugging stuff:
my $debug = 0;
# --------------------------------------------------------------------

# the key is the email address in ALL LOWER CAPS!
# the value is the real name of the person
#
# Unless otherwise noted, the addresses below have been obtained using
# lbdbq.
my %addresses = (
'[e-mail]' => 'Abraham van der Merwe',
'[e-mail]' => 'Georg Acher',
'[e-mail]' => 'Arnaldo Carvalho de Melo',
'[e-mail]' => 'Arnaldo Carvalho de Melo',
'[e-mail]' => 'Adam J. Richter',
'[e-mail]' => 'Andreas Dilger',
'[e-mail]' => 'Andy Grover',
'[e-mail]' => 'Anton Altaparmakov',
'[e-mail]' => 'Anton Altaparmakov',
'[e-mail]' => 'Anton Altaparmakov',
'[e-mail]' => 'Andi Kleen',
'[e-mail]' => 'Andrew Morton',
'[e-mail]' => 'Alan Cox',
'[e-mail]' => 'Anders Gustafsson',
'[e-mail]' => 'Andrea Arcangeli',
'[e-mail]' => 'Andries E. Brouwer',
'[e-mail]' => 'Andrzej Krzysztofowicz',
'[e-mail]' => 'Anton Blanchard',
'[e-mail]' => 'Arjan van de Ven',
'[e-mail]' => 'Arjan van de Ven',
'[e-mail]' => 'Asit K. Mallick', # by Kristian Peters
'[e-mail]' => 'Jens Axboe',
'[e-mail]' => 'Jens Axboe',
'[e-mail]' => 'D. J. Barrow',
'[e-mail]' => 'Ben Collins',
'[e-mail]' => 'Benjamin LaHaise',
'[e-mail]' => 'Michael Beattie', # by Kristian Peters
'[e-mail]' => 'Benjamin Herrenschmidt',
'[e-mail]' => 'Ben Fennema',
'[e-mail]' => 'Brian Gerst',
'[e-mail]' => 'Brad Hards',
'[e-mail]' => 'Bjorn Wesen',
'[e-mail]' => 'Bjorn Helgaas',
'[e-mail]' => 'Boris Itkis', # by Kristian Peters
'[e-mail]' => 'Brett Pemberton',
'[e-mail]' => 'Ken Brownfield',
'[e-mail]' => 'Adrian Bunk',
'[e-mail]' => 'Lennert Buytenhek',
'[e-mail]' => 'Chris Caputo',
'[e-mail]' => 'Christopher Hoover', # by Kristian Peters
'[e-mail]' => 'Samuel S. Chessman',
'[e-mail]' => 'Chris Wright',
'[e-mail]' => 'Christopher Leech',
'[e-mail]' => 'Colin Gibbs',
'[e-mail]' => 'Chris Hanson',
'[e-mail]' => 'Christoph Rohland',
'[e-mail]' => 'Charles-Edouard Ruault',
'[e-mail]' => 'Christopher Yeoh',
'[e-mail]' => 'Martin Dalecki',
'[e-mail]' => 'Dave Jones',
'[e-mail]' => 'David S. Miller',
'[e-mail]' => 'David S. Miller',
'[e-mail]' => 'David Brownell',
'[e-mail]' => 'David Gibson',
'[e-mail]' => 'Davide Libenzi',
'[e-mail]' => 'David Mosberger',
'[e-mail]' => 'David Mosberger',
'[e-mail]' => 'David Mosberger',
'[e-mail]' => 'Dan Streetman',
'[e-mail]' => 'David Howells',
'[e-mail]' => 'Dirk Uffmann',
'[e-mail]' => 'Doug Ledford',
'[e-mail]' => 'Dave McCracken',
'[e-mail]' => 'Denis Oliver Kropp',
'[e-mail]' => 'Douglas Gilbert',
'[e-mail]' => 'David Woodhouse',
'[e-mail]' => 'Eric Brower',
'[e-mail]' => 'Edward Peng',
'[e-mail]' => 'Erich Focht',
'[e-mail]' => 'Steven Cole',
'[e-mail]' => 'Erik Habbinga',
'[e-mail]' => 'Frank Davis',
'[e-mail]' => 'Bakonyi Ferenc',
'[e-mail]' => 'Jürgen E. Fischer',
'[e-mail]' => 'Erich Focht',
'[e-mail]' => 'V. Ganesh',
'[e-mail]' => 'V. Ganesh',
'[e-mail]' => 'Geert Uytterhoeven',
'[e-mail]' => 'Geert Uytterhoeven',
'[e-mail]' => 'George Anzinger',
'[e-mail]' => 'Ghozlane Toumi',
'[e-mail]' => 'Justin T. Gibbs',
'[e-mail]' => 'Justin T. Gibbs',
'[e-mail]' => 'Dr. David Alan Gilbert',
'[e-mail]' => 'Guennadi Liakhovetski',
'[e-mail]' => 'Go Taniguchi',
'[e-mail]' => 'Oleg Drokin',
'[e-mail]' => 'Greg Kroah-Hartman',
'[e-mail]' => 'Grant Grundler',
'[e-mail]' => 'Hanna Linder',
'[e-mail]' => 'Dave Hansen',
'[e-mail]' => 'Christoph Hellwig',
'[e-mail]' => 'Christoph Hellwig',
'[e-mail]' => 'Christoph Hellwig',
'[e-mail]' => 'Christoph Hellwig', # by Kristian Peters
'[e-mail]' => 'Henrique Gobbi',
'[e-mail]' => 'David Gibson',
'[e-mail]' => 'Hirofumi Ogawa', # corrected by himself
'[e-mail]' => 'Colin Slater',
'[e-mail]' => 'Hugh Dickins',
'[e-mail]' => 'Ivan Kokshaysky',
'[e-mail]' => 'Ion Badulescu',
'[e-mail]' => 'Ishan O. Jayawardena',
'[e-mail]' => 'Jan Kara',
'[e-mail]' => 'Jan Harkes',
'[e-mail]' => 'J. A. Magallon',
'[e-mail]' => 'Jamey Hicks',
'[e-mail]' => 'Jani Monoses',
'[e-mail]' => 'Jan-Benedict Glaw',
'[e-mail]' => 'David Ruggiero',
'[e-mail]' => 'David Ruggiero',
'[e-mail]' => 'Jes Degn Sørensen',
'[e-mail]' => 'Jeff Garzik',
'[e-mail]' => 'Jack Hammer',
'[e-mail]' => 'James Morris',
'[e-mail]' => 'Johannes Erdfelt',
'[e-mail]' => 'John Clemens',
'[e-mail]' => 'John Kim',
'[e-mail]' => 'James Simmons',
'[e-mail]' => 'James Simmons',
'[e-mail]' => 'Jean Tourrilhes',
'[e-mail]' => 'Jean Tourrilhes',
'[e-mail]' => 'Karol Kasprzak', # by Kristian Peters
'[e-mail]' => 'Patrick McHardy',
'[e-mail]' => 'Kai Germaschewski',
'[e-mail]' => 'Kai Reichert',
'[e-mail]' => 'Kai Germaschewski',
'[e-mail]' => 'Kanoj Sarcar', # sent by Arnaldo Carvalho de Melo
'[e-mail]' => 'Kanoj Sarcar',
'[e-mail]' => 'Keith Owens',
'[e-mail]' => 'Kasper Dupont',
'[e-mail]' => 'Kent Yoder',
'[e-mail]' => 'Khalid Aziz',
'[e-mail]' => 'Khalid Aziz',
'[e-mail]' => 'Erik Inge Bolsø',
'[e-mail]' => 'Gerd Knorr',
'[e-mail]' => 'Gerd Knorr',
'[e-mail]' => 'Robert Kuebel',
'[e-mail]' => 'Alexey Kuznetsov',
'[e-mail]' => 'Harald Welte',
'[e-mail]' => 'Luca Barbieri',
'[e-mail]' => 'Liyang Hu',
'[e-mail]' => 'Larry McVoy',
'[e-mail]' => 'Maciej W. Rozycki',
'[e-mail]' => 'Manfred Spraul',
'[e-mail]' => 'Marc Boucher',
'[e-mail]' => 'Marcelo Tosatti',
'[e-mail]' => 'Marcelo Tosatti',
'[e-mail]' => 'Martin Schwenke',
'[e-mail]' => 'Chris Mason',
'[e-mail]' => 'Maksim Krasnyanskiy',
'[e-mail]' => 'Marc-Christian Petersen',
'[e-mail]' => 'Michael Elizabeth Chastain',
'[e-mail]' => 'Michal Jaegermann',
'[e-mail]' => 'Mike Phillips',
'[e-mail]' => 'Mikael Pettersson',
'[e-mail]' => 'Miles Lane',
'[e-mail]' => 'Milton Miller', # by Kristian Peters
'[e-mail]' => 'Ingo Molnar',
'[e-mail]' => 'Martin Mares',
'[e-mail]' => 'Mirko Lindner',
'[e-mail]' => 'Mark McClelland',
'[e-mail]' => 'Patrick Mochel',
'[e-mail]' => 'Patrick Mochel',
'[e-mail]' => 'Matt Wilson',
'[e-mail]' => 'Itai Nahshon',
'[e-mail]' => 'Nathan Scott',
'[e-mail]' => 'Neil Brown',
'[e-mail]' => 'Nemosoft Unv.',
'[e-mail]' => 'Nicolas Pitre',
'[e-mail]' => 'Niels Kristian Bech Jensen',
'[e-mail]' => 'Olaf Hering',
'[e-mail]' => 'Dave Olien',
'[e-mail]' => 'Oliver Neukum',
'[e-mail]' => 'Oliver Neukum',
'[e-mail]' => 'Oskar Schirmer', # sent by himself
'[e-mail]' => 'Paul Gortmaker',
'[e-mail]' => 'Paul Fulghum',
'[e-mail]' => 'Paul Mackerras',
'[e-mail]' => 'Paul Mackerras',
'[e-mail]' => 'Paul Mackerras',
'[e-mail]' => 'Pavel Machek',
'[e-mail]' => 'Andrey Panin',
'[e-mail]' => 'Jaroslav Kysela',
'[e-mail]' => 'Jaroslav Kysela',
'[e-mail]' => 'Peter Samuelson',
'[e-mail]' => 'Peter Chubb',
'[e-mail]' => 'Peter Osterlund',
'[e-mail]' => 'Paul Larson',
'[e-mail]' => 'Paul Menage',
'[e-mail]' => 'Ingo Albrecht',
'[e-mail]' => 'Daniel Quinlan',
'[e-mail]' => 'Juan Quintela',
'[e-mail]' => 'Randy Dunlap',
'[e-mail]' => 'Udo A. Steinberg',
'[e-mail]' => 'Hans Reiser',
'[e-mail]' => 'Bob Miller',
'[e-mail]' => 'Richard Gooch',
'[e-mail]' => 'Richard Gooch',
'[e-mail]' => 'Richard Hirst',
'[e-mail]' => 'Rik van Riel',
'[e-mail]' => 'Roger Luethi',
'[e-mail]' => 'Romain Lievin',
'[e-mail]' => 'Russell King',
'[e-mail]' => 'Russell King',
'[e-mail]' => 'Robert Love',
'[e-mail]' => 'Rob Radez',
'[e-mail]' => 'Robert Olsson',
'[e-mail]' => 'François Romieu',
'[e-mail]' => 'Richard Henderson',
'[e-mail]' => 'Rui Sousa',
'[e-mail]' => 'Rusty Russell',
'[e-mail]' => 'Randy Hron',
'[e-mail]' => 'Thomas Sailer',
'[e-mail]' => 'Eric Sandeen',
'[e-mail]' => 'Santiago A. Nullo', # sent by self
'[e-mail]' => 'sawa',
'[e-mail]' => 'Andreas Schwab',
'[e-mail]' => 'Scott Anderson',
'[e-mail]' => 'Sebastian Dröge',
'[e-mail]' => 'Stephen Rothwell',
'[e-mail]' => 'Dave Kleikamp',
'[e-mail]' => 'Simon Burley',
'[e-mail]' => 'Stuart Lynne',
'[e-mail]' => 'Nathan Dabney',
'[e-mail]' => 'Simon Evans', # by Kristian Peters
'[e-mail]' => 'Jack Steiner',
'[e-mail]' => 'Stelian Pop',
'[e-mail]' => 'Tomas Szepe',
'[e-mail]' => 'Taisuke Yamada',
'[e-mail]' => 'Tom Callaway',
'[e-mail]' => 'Tero Pirkkanen', # by Kristian Peters
'[e-mail]' => 'Tim Hockin',
'[e-mail]' => 'Tigran Aivazian',
'[e-mail]' => 'Tim Schmielau',
'[e-mail]' => 'Osamu Tomita',
'[e-mail]' => 'Anthony J. Breeds-Taurima',
'[e-mail]' => 'Linus Torvalds',
'[e-mail]' => 'Linus Torvalds',
'[e-mail]' => 'Linus Torvalds',
'[e-mail]' => 'Linus Torvalds',
'[e-mail]' => 'Tom Rini',
'[e-mail]' => 'Tom Rini',
'[e-mail]' => 'Trond Myklebust',
'[e-mail]' => 'Thierry Vignaud',
'[e-mail]' => 'Tim Waugh',
'[e-mail]' => 'Urban Widmark',
'[e-mail]' => 'Joshua Uziel',
'[e-mail]' => 'Petr Vandrovec',
'[e-mail]' => 'Alexander Viro',
'[e-mail]' => 'Vojtech Pavlik',
'[e-mail]' => 'Vojtech Pavlik',
'[e-mail]' => 'Vojtech Pavlik',
'[e-mail]' => 'Wim Van Sebroeck',
'[e-mail]' => 'Wolfgang Fritz', # by Kristian Peters
'[e-mail]' => 'William Stinson',
'[e-mail]' => 'Kasparek Tomas',
'[e-mail]' => 'Pete Zaitcev',
'[e-mail]' => 'Roman Zippel',
'[e-mail]' => 'Zwane Mwaikambo',
'~~~~~~thisentrylastforconvenience~~~~~' => 'Cesar Brutus Anonymous'
);

my %address_unknown;

# get name associated to an email address
sub rmap_address {
  my @o = map {defined $addresses{$_} ? $addresses{$_} :
		 scalar (($address_unknown{$_} = 1), $_); }
          map { lc; } @_;
  return wantarray ? @o : $o[0];
}

# case insensitive string comparison
# FIXME: use locale?
sub caseicmp { uc($a) cmp uc($b) };

my ($author, $address, $name);
# * $address is always an email address
# * $author can be the email address or Joe N. Sixpack II <[e-mail]>
#   (ready formatted to print)
# * $name is the name (Joe N. Sixpack II) or the mail address
#   (<[e-mail]>) 

sub get_name()   { return $name; }
sub get_author() { return $author; }

# This table maps MODE => { myhash }
# myhash knows the keys "index" and "print" to choose the respective functions
my %table = 
  (
   'oneline' => { 'index' => \&get_name,
		  'print' => \&print_oneline },
   'terse'   => { 'index' => \&get_name,
		  'print' => \&print_terse },
   'grouped' => { 'index' => \&get_author,
		  'print' => \&print_grouped },
   'full'    => { 'index' => \&get_author,
		  'print' => \&print_full }
  );

# temp store
my $indexby;

# Global store #############
# Store log entries.
my %log;
# We store our options here.
my %opt;

# As we are parsing, the log is accumulated in the @cur array.  When
# we are done with one item (end of input or new mail address found),
# stuff a copy of this @cur array into the %log hash.
sub append_item(@)
{
  my @cur = @_;
  return unless @cur;
  return unless &$indexby;
  $log{&$indexby} = () unless defined $log{&$indexby};

  # strip trailing blank lines
  my $t;
  while (($t = pop(@cur)) eq '') { };
  push @cur, $t;

  # store the array
  push @{$log{&$indexby}}, [@cur];
}

# Remove duplicates from hash, without changing the order.
# Prefix duplicates with the count.
sub countdups(@) {
  my %t;
  croak "do not call removedups() in scalar context" unless wantarray;
  my @u = grep (!$t{lc $_}++, @_);
  return map {
    $t{lc $_} > 1 ? sprintf("%d x ", $t{lc $_}) . $_ : $_; 
  } @u;
}

# Remove duplicates from array, without changing the order. The
# duplicates need not follow each other, so A B A is properly
# stripped down to A B
sub removedups(@) {
  my %t;
  croak "do not call removedups() in scalar context" unless wantarray;
  return grep (!$t{lc $_}++, @_);
}

# Compress the hash passed in, depending on the --compress and --count
# options in the %opt hash.
sub compress(@) {
  croak "do not call compress() in scalar context" unless wantarray;
  if ($opt{compress}) {
    if ($opt{count}) {
      return countdups(@_);
    } else {
      return removedups(@_);
    }
  } else {
    return @_;
  }
}

# report write error, exit
# do not return
sub write_error() {
  croak "Write error: $!\nAborting";
  exit (1);
}

# implementation of "grouped" output:
# author:
#   first line of log1
#   first line of log2
sub print_grouped() {
  for (sort caseicmp keys %log) {
    my @lines = compress(map { $_->[0] . "\n"; } @{$log{$_}});
    if ($opt{width}) {
      @lines = map { expand(wrap($indent1, $indent, ($_))); } @lines;
    } else {
      @lines = map { "$indent1$_" } @lines;
    }
    printtag($_) or write_error();
    print join("", @lines), "\n" or write_error();
  }
}

# implementation of "full" output
# author:
#   o log1
#     more information on changeset1
#   o log2
#     more information on changeset2 
sub print_full() {
  for (sort caseicmp keys %log) {
    printtag($_) or write_error();
    foreach (compress(@{$log{$_}})) {
      my @lines = map { s/^\t//; "$_\n"; } @$_;
      if ($opt{width}) {
	@lines = expand(wrap($indent1, $indent, @lines));
      } else {
	@lines = map { "$indent$_"; } @lines;
	substr($lines[0], $[, length($indent1)) = $indent1;
      }
      print join("", @lines), "\n"  or write_error();
    }
  }
  print "\n"  or write_error();
}

# implementation of "terse" output
# with --swap          without --swap
# author1: log1        log1    (author1)
# author1: log2        log2    (author2)
# author2: log3        log3    (author3)
sub print_terse() {
  for (sort caseicmp keys %log) {
    my $a = $_;
    if ($opt{width}) {
      if ($opt{swap}) {
	foreach (compress(map { $_->[0]; } @{$log{$_}})) {
	  my @lines = expand(wrap($indent1, $indent, ("$a: $_")));
	  print join("\n", @lines), "\n"  or write_error();
	}
      } else {
	# width, but not swap set
	foreach (compress(map { $_->[0]; } @{$log{$_}})) {
	  my @addr = expand(split(/\n/, wrap('', $indent, " ($a)")));
	  my @lines = expand(split(/\n/, wrap($indent1, $indent, ($_))));

	  if (length($lines[$#lines]) + length($addr[0]) > $opt{width}) {
	    push @lines, '';
	  }
	  $lines[$#lines] .= sprintf("%*s", $opt{width}
				     - length($lines[$#lines]), $addr[0]);
	  shift @addr;
	  print join("\n", @lines), "\n"  or write_error();
	  foreach (@addr) {
	    printf "%*s\n", $opt{width}, $_  or write_error();
	  }
	}
      }
    } else {
      # using the ?: operator within the map is more maintainable, but
      # less efficient.
      if ($opt{swap}) {
	print join("\n", map { "$indent1$a: $_" }
		   compress(map { $_->[0]; } @{$log{$_}})), "\n"
		     or write_error();
      } else {
	print join("\n", map { "$indent1$_ ($a)" } 
		   compress(map { $_->[0]; } @{$log{$_}})), "\n"
		     or write_error();
      }
    }
  }
}

# implementation of "oneline" output
# which is similar to terse but reformats to one line exactly
# with --swap          without --swap
# author1: log1        log1    (author1)
# author1: log2        log2    (author2)
# author2: log3        log3    (author3)
sub print_oneline() {
  for (sort caseicmp keys %log) {
    my $a = $_;
    if ($opt{width}) {
      if ($opt{swap}) {
	foreach (compress(map { $_->[0]; } @{$log{$_}})) {
	  printf "%-.*s\n", $opt{width}, $indent1 . "$a: $_"
	    or write_error();
	}
      } else {
	foreach (compress(map { $_->[0]; } @{$log{$_}})) {
	  my $l = $opt{width} - length($indent1) - length($a) - 3;
	  printf "%s%-*.*s (%s)\n", $indent1, $l, $l, $_, $a;
	}
      }
    } else {
      # not $opt{width} -> same as print_terse
      print_terse();
    }
  }
}

# Read a file and parse it into the %log hash.
sub parse_file($ ) {
  my @prolog;
  local $_;
  my $fn = shift;
  my $fh;
  # Treat '-' as stdin -- IO::File won't do this.
  if ($fn eq '-') {
    $fh = new IO::Handle;
    $fh->fdopen(fileno(STDIN), "r")
      or die "cannot open stdin: $!\nAborting";
  } else {
    $fh = new IO::File;
    $fh->open($fn, "r")
      or die "cannot open \"$fn\": $!\nAborting";
  }

  my @cur = ();

  my $first = 0;
  undef $address;

  while($_ = $fh -> getline) {
    chomp;
    $_ = expand($_);
    # if we are in multi mode, if we encounter a non-address left-justified line,
    # flush all data and print the header. The defined $address trick lets this
    # only trigger to switch back from "log entry" to "prolog" mode
    if (defined $address and $opt{multi} and m|^[^<[:space:]]|) {
      append_item(@cur); @cur = ();
      doprint(@prolog);
      print "\n" or write_error(); # print blank line between changelogs
      @prolog = ($_);
      undef %log;
      undef $address;
    # go figure if a line starts with an address, if so, take it
    # resolve the address to a name if possible
    } elsif (m|^<([^>]+)>|) {
      append_item(@cur); @cur = ();
      $address = $1;
      $name = rmap_address($address);
      if ($name ne $address) {
	$author = $name . ' <' . $address . '>';
      } else {
	$author = '<' . $address . '>';
      }
      $first = 1;
    # we have a "first" line after an address, take it, strip common redundant tags
    } elsif ($first) {
      # kill "PATCH" tag
      s/^\s*\[PATCH\]//;
      s/^\s*PATCH//;
      s/^\s*[-:]+\s*//;
      # strip trailing colon
      s/:\s*$//;
      # kill leading and trailing whitespace for consistent indentation
      s/^\s+//; s/\s+$//;

      push @cur, $_;
      $first = 0;
    # second or subsequent lines
    } elsif (defined $address) {
      push @cur, $_;
    # store header before a changelog
    } else {
      push @prolog, $_;
    }
  }

  if ($fh -> error) {
    die "Error while reading from \"$fn\": $!";
  }

  # at file end, flush @cur array to %log.
  append_item(@cur);

  croak unless wantarray;
  return @prolog;
}

# print a word-wrapped name or mail address, followed by a trailing colon.
# used by print_grouped and print_full
# passes the return value of print back up
sub printtag($ ) {
  my $a = shift;
  $a .= ':';
  return print $opt{width} ? expand(wrap("", "", ($a))) : $a, "\n";
}

# === MAIN PROGRAM ===============================================
# Command line arguments
# What options do we support?
my @opts = ("help|?|h", "man", "mode=s", "compress!", "count!", "width:i",
	    "swap!", "merge!", "warn!", "multi!");

# How do we parse them?
if ($Getopt::Long::VERSION gt '2.24') {
  Getopt::Long::Configure("gnu_getopt");
}

# set default options
$opt{mode} = 'grouped';
$opt{warn} = 1;

# Parse from environment, temporarily storing the original @ARGV.
if (defined $ENV{LINUXKERNEL_BK_FMT}) {
  my @savedargs = @ARGV;
  @ARGV = parse_line('\s+', 0, $ENV{LINUXKERNEL_BK_FMT});
  GetOptions(\%opt, @opts)
    or pod2usage(-verbose => 0,
		 -message => $0 . ': error in $LINUXKERNEL_BK_FMT');
  push @ARGV, @savedargs;
}

# Parse command line. Handle help, check for errors.
GetOptions(\%opt, @opts) or pod2usage(-verbose => 0);
pod2usage(-verbose => 1) if $opt{help};
pod2usage(-verbose => 2) if $opt{man};
pod2usage(-verbose => 0,
	  -message => ("$0: Unknown mode specified.\nValid modes are:\n    "
		       . join(" ", sort keys %table) . "\n"))
  unless defined $table{$opt{mode}};
pod2usage(-verbose => 0,
	  -message => "$0: No files given, refusing to read from a TTY.")
  if ((@ARGV == 0) && (-t STDIN));
pod2usage(-verbose => 0,
	  -message => "$0: You cannot use --merge and --multi at the same time.")
  if ($opt{merge} and $opt{multi});

# Shortcut for programmer convenience :-)
$indexby = $table{$opt{mode}}->{'index'};

# --count implies --compress
if ($opt{count}) { $opt{compress} = 1; }

# if --width is without argument or the argument is zero,
# try to figure $COLUMNS or fall back to 80.
if (exists $opt{width} and not $opt{width}) {
  $opt{width} = $ENV{COLUMNS} ? $ENV{COLUMNS} : 80;
}

# Print the passed-in array linewise, checking for write errors
# Then call the configured function to print %log formatted
sub doprint(@ ) {
  print join("\n", @_), "\n" or write_error();
  &{$table{$opt{mode}}->{print}};
}

# --------------------------------------------------------------------
# Global initializations
$Text::Tabs::tabstop = 8;
$Text::Wrap::huge = 'wrap';
if ($opt{width}) {
  $Text::Wrap::columns = $opt{width};
}

# Main program
unshift(@ARGV, '-') unless @ARGV;

if ($debug) {
  print STDERR "DEBUG: Options summary:\n";
  while (my ($k, $v) = each %opt) { print STDERR "DEBUG:   '$k' => '$v'\n"; }
  print STDERR "DEBUG: Arguments summary:\n";
  foreach (@ARGV) { print STDERR "DEBUG:   '$_'\n"; }
}

my @prolog;

# NOTE: if $opt{merge} is set, all file prologs are suppressed.
while ($ARGV = shift) {
  push @prolog, parse_file($ARGV);
  if (not $opt{merge}) {
    doprint(@prolog);
    undef %log;
  }
  undef @prolog;
}

if ($opt{merge}) {
  doprint(());
}

# Warn about unknown addresses
if ($opt{warn}) {
  foreach (sort caseicmp keys %address_unknown) {
    print STDERR "Warning: unknown address \"$_\"\n" or write_error();
  }
}

__END__
# --------------------------------------------------------------------
# $Log: lk-changelog.pl,v $
# Revision 0.21  2002/05/29 11:45:48  emma
# * Implement --mode=oneline.
# * Expand tabs in input lines (tab stops are spaced 8 columns away from each other).
# * Bugfix --multi mode: all append_item to flush @cur before printing.
# * Restore prolog detection in --multi mode for efficiency.
# * Undo the "unexpand()" that Text::Wrap does, it breaks our line width
#   calculation. In the long run, a replacement for Text::Wrap must be
#   found that does not unexpand().
#
# Revision 0.20  2002/05/29 10:44:35  emma
# New --multi option that states multiple changelogs are in the same file.
#
# Revision 0.19  2002/05/29 10:27:21  emma
# New option: --[no]warn: Warn about unknown addresses. By default
# enabled, use --nowarn to suppress.
#
# Revision 0.18  2002/05/29 10:17:00  emma
# New addresses.
#
# Revision 0.17  2002/05/25 23:32:49  emma
# Four new addresses.
#
# Revision 0.16  2002/05/22 15:52:26  emma
# Fix deliberate typo in use Pod::Usage that was left over from debugging.
#
# Revision 0.15  2002/05/22 14:05:13  emma
# Sort addresses/names case insensitively (not locale aware).
# Heed quotes when parsing $ENV{LINUXKERNEL_BK_FMT}. As I don't
# currently have Perl 5.004 to test the older Text::ParseWords
# implementation, script now requires Perl 5.005.
# Do not require Pod::Usage, but warn if it's missing.
#
# Revision 0.14  2002/05/22 12:39:59  emma
# Fold the print function dispatcher into %table.
# Parse files on command line individually, but allow to treat them as
# one with a new --merge option.
# Make @cur local to the parse function.
# Die on read errors on input files. Use IO::Handle to read files.
#
# Revision 0.13  2002/05/21 12:42:46  emma
# Add 3 mail addresses.
# Add commentary to the code.
# Check for write errors on STDOUT and die if one happens.
#
# Revision 0.12  2002/05/18 16:54:50  emma
# Make --compress work in terse mode.
# New feature: --swap in terse mode swaps address and log entry.
#
# Revision 0.11  2002/05/18 16:43:30  emma
# Support 'terse' mode.
#
# Revision 0.10  2002/05/18 16:15:10  emma
# Another set of addresses.
#
# Revision 0.9  2002/05/18 16:06:43  emma
# Dozens of new addresses.
#
# Revision 0.8  2002/05/18 15:46:01  emma
# 21 new addresses.
#
# Revision 0.7  2002/05/16 13:57:37  emma
# Add some documentation.
#
# Revision 0.6  2002/05/16 13:55:24  emma
# Fix shift ambiguity in printtag().
#
# Revision 0.5  2002/05/16 13:51:43  emma
# Implement grouped and full modes.
#
# Revision 0.4  2002/05/16 12:07:17  emma
# Add some POD.
# Do options and environment parsing.
# Prepare multiple output modes (only grouped supported at the moment.)
#
# Revision 0.3  2002/05/13 16:11:34  emma
# Compress identical ChangeLog lines (they need not be subsequent, note
# this feature has O(n^2) behaviour, where n is the number of stored
# ChangeLog lines per respective author):
#   Soft-fp fix:
#   Soft-fp fix:
# becomes:
#   2 x Soft-fp fix:
#
# Revision 0.2  2002/05/13 10:40:32  emma
# Only consider e-mail addresses that are left-justified.
# Suggested by Greg Kroah-Hartman <[e-mail]>.
#
=head1 NAME

lk-changelog.pl - Reformat BitKeeper ChangeLog for Linux Kernel

=head1 SYNOPSIS

lk-changelog.pl [options] [file [...]]

Try lk-changelog.pl --help or lk-changelog.pl --man for more information.

=head1 OPTIONS

 -h, --help          print this short help
     --man           print the manual page for this program

     --[no]compress  if true, suppress duplicate entries
     --[no]count     if true, fold duplicate entries into one,
                     prefixing it with the count. Implies --compress.
     --[no]swap      in terse and oneline mode, swap address and log entry.
     --[no]merge     treat all files on command line as one big file
                     and suppress the prolog
     --[no]multi     states that multiple changelogs are in one file
     --[no]warn      warn about unknown addresses. Default: set!

     --mode=MODE     specify the output format (use --man to find out more)
     --width[=WIDTH] specify the line length, if omitted: $COLUMNS or 80.
                     text lines will not exceed this length.

Warning: Neither --compress nor --count are currently functional with
--mode=full.

=head1 DESCRIPTION

Reformats BitKeeper ChangeLog for Linux Kernel.

=head1 ENVIRONMENT

=over

=item LINUXKERNEL_BK_FMT

Default options. These have the same meaning and syntax as the command
line options and are parsed before them, so you can override defaults
set in this variable on the command line. B<Example:> If you put
--swap here and --noswap on your command line, --noswap takes
precedence.

=back

=head1 EXAMPLES

=over

=item Reformat ChangeLog-2.5.17, displaying all changes grouped by
  their author (that is the default mode, but we specify it anyways),
  with 76 character wide lines:

 lk-changelog.pl --mode=grouped --width=76 ChangeLog-2.5.17

=item Reformat ChangeLog-2.5.18, displaying all changes and their
      author on in "-ac changelog style", with 80 character wide lines:

 lk-changelog.pl --mode=terse --width=80 ChangeLog-2.5.18

=item Reformat 2.4.19-pre ChangeLogs (several in one file) from your mailer:

Use the pipe command to pipe the mail into:

 lk-changelog.pl --multi --mode=terse --width=80

=back

=head1 AUTHORS

=over

=item * Matthias Andree <[e-mail]>

=item * Marcus Alanen <[e-mail]>

=item * Tomas Szepe <[e-mail]>

=back

=head1 BUGS

=over

=item * The header is not wrapped for --width character wide lines.

=item * The implementation is not yet finished.

=item * This manual page is incomplete.

=item * --compress does not currently work with --mode=full.

=item * does not detect if the changelog is already summarized (as in Marcelo's 2.4.19-pre9 announcement on the list, 

=back

=head1 TODO

=over

=item * --compress-me-harder

 To merge
   o iget_locked  [1/6]
   o iget_locked  [2/6]
   ...
   o iget_locked  [6/6]
 into
   o iget_locked  [1..6/6]

=item * Detect if first line is just a line of a paragraph...

...or if it's a paragraph on its own. If it's a line of a paragraph, try to cut
at last full stop or append ellipsis.

=item * Offer sort by last name

=back

=cut